くだけちるエフェクト（改訂篇）

先月作ったくだけちるエフェクトの改良版。

破片の形状生成アルゴリズムを Delaunay 分割に変更し、さらに各破片の飛び散り方を 3 次元的にしてみた。

前回と違ってクリック時にフラッシュ効果を入れていないのは、そんなごまかしをしなくても割とまともに見られるようになったからである。

---

【ソースコード】

このサンプルがサポートするのは、以下の Scene インタフェースを実装した状態クラス間の遷移のみである。

view plainprint?

1. // **************************************  
2. // シーンを司るインタフェースクラス  
3. //   
4. // updateメソッドをオーバーライドして使う  
5. // 戻り値は、次に遷移するシーンオブジェクト  
6. // （遷移しない場合はthisポインタ）  
7. // **************************************  
8. interface Scene {  
9.   Scene update();  
10.   void setEnable(boolean isEnable);    
11. }  

// **************************************
// シーンを司るインタフェースクラス
// 
// updateメソッドをオーバーライドして使う
// 戻り値は、次に遷移するシーンオブジェクト
// （遷移しない場合はthisポインタ）
// **************************************
interface Scene {
  Scene update();
  void setEnable(boolean isEnable);  
}

で。

肝心の状態遷移効果に関する処理は、先日の Delaunay 分割を加えてこんな感じになった。

+ expand sourceview plainprint?

1. // ∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴  
2. //   
3. // 状態遷移に関するクラス群  
4. //  
5. // ∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵  
6.   
7.   
8. // **************************************  
9. //  
10. // 画面遷移用クラス  
11. //  
12. // **************************************  
13. class StateTransitionEffect implements Scene {  
14.   
15.   // ======================================  
16.   // 遷移にかかる時間と、  
17.   // フェード効果発現までの時間（変更可能）  
18.   // ======================================  
19.   private final int MAX_TIME   = 90;  
20.   private final int FADE_DELAY = 80;  
21.   
22.   private PImage nextSceneImage;  
23.   private Fragments fragments;  
24.   private int time;  
25.   private Scene cur, next;  
26.     
27.   // ======================================  
28.   // コンストラクタ  
29.   //   
30.   // Scene  
31.   //  - cur  : 前状態  
32.   //  - next : 次状態  
33.   // ======================================  
34.   StateTransitionEffect(Scene cur, Scene next) {  
35.     this.cur = cur;  
36.     this.next = next;  
37.       
38.     nextSceneImage = createImage(width, height, RGB);  
39.   
40.     cur.setEnable(false);  
41.     next.setEnable(false);  
42.       
43.     fragments = new Fragments(50);  
44.     time = 0;  
45.   }  
46.     
47.   Scene update(){  
48.     camera();  
49.     noStroke();  
50.     next.update();  
51.       
52.     int a;  // アルファ値（フェード効果で使用）  
53.       
54.     loadPixels();  
55.     for(int i = 0; i < pixels.length; i++)  
56.       nextSceneImage.pixels[i] = pixels[i];  
57.     background(nextSceneImage);  
58.       
59.     // 次状態のフェードイン効果  
60.     /* -------------------------------------------------- 
61.     a = (int)(255 * (float)(MAX_TIME - time) / MAX_TIME); 
62.     fill(0, a);    noSmooth(); 
63.     rect(0, 0, width, height); 
64.     -------------------------------------------------- */  
65.       
66.     // 破片の描画  
67.     fragments.update();  
68.       
69.     // 破片のフェードアウト効果  
70.     if (FADE_DELAY <= time) {  
71.       a = (int)(255*(float)(time-FADE_DELAY)/(MAX_TIME-FADE_DELAY));  
72.   
73.       loadPixels();  
74.       // アルファ合成  
75.       for(int i = 0; i < pixels.length; i++) {  
76.         int fg = nextSceneImage.pixels[i];  
77.         int bg = pixels[i];  
78.           
79.         int fR = (0x00FF0000 & fg) >>> 16;  
80.         int fG = (0x0000FF00 & fg) >>> 8;  
81.         int fB =  0x000000FF & fg;  
82.         
83.         int bR = (0x00FF0000 & bg) >>> 16;  
84.         int bG = (0x0000FF00 & bg) >>> 8;  
85.         int bB =  0x000000FF & bg;  
86.         
87.         int rR = (((fR - bR) * a) >>> 8 ) + bR;  
88.         int rG = (((fG - bG) * a) >>> 8 ) + bG;  
89.         int rB = (((fB - bB) * a) >>> 8 ) + bB;  
90.           
91.         pixels[i] = 0xFF000000 | (rR << 16) | (rG << 8) | rB;  
92.       }  
93.       updatePixels();  
94.     }  
95.       
96.     if(time++ < MAX_TIME) return this;  
97.       
98.     next.setEnable(true);  
99.     return next;  
100.   }  
101.     
102.   void setEnable(boolean isEnable) {   
103.     /* なにもしない */  
104.   }  
105. }  
106.   
107. // **************************************  
108. //  
109. // 破片の集合クラス  
110. //  
111. // **************************************  
112. class Fragments {  
113.   PImage tex;  
114.   List<Fragment> f;  
115.     
116.   Fragments(int nPoints) {  
117.     tex = createImage(width, height, RGB);  
118.     loadPixels();  
119.     for(int i = 0; i < pixels.length; i++) {  
120.       tex.pixels[i] = pixels[i];  
121.     }  
122.       
123.     // 破片セット  
124.     f = new ArrayList<Fragment>();  
125.       
126.     // Delaunay分割  
127.     List<PVector> pList = new ArrayList<PVector>();  
128.     pList.add(new Point(0, 0));  
129.     pList.add(new Point(width, 0));  
130.     pList.add(new Point(width, height));  
131.     pList.add(new Point(0, height));  
132.     for(int i = 0; i < nPoints; i++) {  
133.       pList.add(new Point(random(width), random(height)));  
134.     }  
135.     DelaunayTriangles delaunay = new DelaunayTriangles(pList);  
136.       
137.     // Delaunay三角集合をリスト化  
138.     HashSet tSet = delaunay.getDelaunayTriangulationSet();  
139.     for(Iterator it = tSet.iterator(); it.hasNext();) {  
140.       f.add(new Fragment((Triangle)it.next(), tex));  
141.     }  
142.   }  
143.     
144.   void update() {  
145.     for(Iterator it = f.iterator(); it.hasNext();) {  
146.       Fragment fragment = (Fragment)it.next();  
147.       fragment.update();  
148.     }  
149.   }  
150. }  
151.   
152. // **************************************  
153. //  
154. // 破片クラス  
155. //  
156. // **************************************  
157. class Fragment {  
158.   // PVector[] texCoords;  
159.   PVector[] vertices;  
160.   PImage tex;  // テクスチャ  
161.     
162.   // 並進成分・回転角  
163.   private float x, y, z, rx, ry, rz;  
164.   private float dx, dy, dz, drx, dry, drz;  
165.   private float ddx, ddy, ddz;  
166.     
167.   // 与えられた三角形の重心  
168.   private float cx, cy, cz;  
169.     
170.   Fragment(Triangle t, PImage tex) {  
171.     this.tex = tex;  
172.       
173.     // 頂点座標をセット  
174.     vertices = new PVector[3];  
175.     vertices[0] = t.p1;  
176.     vertices[1] = t.p2;  
177.     vertices[2] = t.p3;  
178.       
179.     // 重心を計算  
180.     cx = (t.p1.x + t.p2.x + t.p3.x)/3.0;  
181.     cy = (t.p1.y + t.p2.y + t.p3.y)/3.0;  
182.     cz = (t.p1.z + t.p2.z + t.p3.z)/3.0;  
183.       
184.     // 並進・回転の初期値を設定  
185.     x = y = z = 0;  
186.     rx = ry = rz = 0;  
187.       
188.     // ======================================  
189.     // 速度・加速度を設定（変更可能）  
190.     // ======================================  
191.     dx =  random(-0.5, 0.5);  
192.     dy = -random( 1  , 6  );  
193.     dz =  random(-0.5, 0.5);  
194.       
195.     ddx = 0;  
196.     ddy = random(0.2, 0.5);  
197.     ddz = 0;  
198.   
199.     drx = radians(random(-2, 2));  
200.     dry = radians(random(-2, 2));  
201.     drz = radians(random(-2, 2));      
202.   }  
203.     
204.   void update() {  
205.     noStroke();  
206.     fill(255);  
207.     lights();  
208.   
209.     pushMatrix();  
210.     // 並進  
211.     translate(cx + x, cy + y, cz + z);  
212.       
213.     // 回転    
214.     rotateX(rx); rotateZ(rz); rotateY(ry);  
215.       
216.     // 並進  
217.     translate(-cx, -cy, -cz);  
218.   
219.     textureMode(IMAGE);  
220.     beginShape(TRIANGLES);  
221.     texture(tex);  
222.     for(int i = 0; i < vertices.length; i++) {  
223.       vertex(vertices[i].x, vertices[i].y,  
224.              vertices[i].x, vertices[i].y);  
225.     }  
226.     endShape();  
227.     popMatrix();  
228.     noLights();  
229.       
230.     x  += dx;  y  += dy;  z  += dz;  
231.     rx += drx; ry += dry; rz += drz;  
232.     dx += ddx; dy += ddy; dz += ddz;  
233.   }  
234. }  
235.   
236.   
237. // ∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴  
238. //   
239. // Delaunay分割に関するクラス群  
240. //  
241. // ∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵  
242.   
243. // **************************************  
244. //  
245. // Delaunay分割用クラス  
246. //  
247. // **************************************  
248.   
249. class DelaunayTriangles {  
250.   private List<PVector> pointList;  
251.   // ======================================  
252.   // コンストラクタ  
253.   // 与えられた点のリストを基にDelaunay分割を行う  
254.   // ======================================  
255.   public DelaunayTriangles(List<PVector> pointList) {  
256.     this.pointList = pointList;  
257.   }  
258.     
259.     
260.   // ======================================  
261.   // Delaunay三角分割を行う  
262.   // ======================================  
263.   public HashSet<Triangle>  
264.       getDelaunayTriangulationSet() {  
265.       
266.     // 三角形リストを初期化  
267.     HashSet<Triangle> triangleSet = new HashSet<Triangle>();  
268.       
269.     // 巨大な外部三角形をリストに追加  
270.     Triangle hugeTriangle = getHugeTriangle();  
271.     triangleSet.add(hugeTriangle);  
272.   
273.     try {  
274.       // --------------------------------------  
275.       // 点を逐次添加し、反復的に三角分割を行う  
276.       // --------------------------------------  
277.       for(Iterator pIter = pointList.iterator(); pIter.hasNext();) {  
278.         Object element = pIter.next();  
279.         Point p = element instanceof Point ?   
280.             (Point)element : new Point((PVector)element);  
281.           
282.         // --------------------------------------  
283.         // 追加候補の三角形を保持する一時ハッシュ  
284.         // --------------------------------------  
285.         // 追加候補の三角形のうち、「重複のないものだけ」を  
286.         // 三角形リストに新規追加する  
287.         //          → 重複管理のためのデータ構造  
288.         // tmpTriangleSet  
289.         //  - Key   : 三角形  
290.         //  - Value : 重複していないかどうか  
291.         //            - 重複していない : true  
292.         //            - 重複している   : false  
293.         // --------------------------------------  
294.         HashMap<Triangle, Boolean> tmpTriangleSet   
295.           = new HashMap<Triangle, Boolean>();  
296.   
297.         // --------------------------------------  
298.         // 現在の三角形リストから要素を一つずつ取り出して、  
299.         // 与えられた点が各々の三角形の外接円の中に含まれるかどうか判定  
300.         // --------------------------------------  
301.         for(Iterator tIter=triangleSet.iterator(); tIter.hasNext();){  
302.           // 三角形リストから三角形を取り出して…  
303.           Triangle t = (Triangle)tIter.next();  
304.                 
305.           // その外接円を求める。  
306.           Circle c = getCircumscribedCirclesOfTriangle(t);  
307.                 
308.           // --------------------------------------  
309.           // 追加された点が外接円内部に存在する場合、  
310.           // その外接円を持つ三角形をリストから除外し、  
311.           // 新たに分割し直す  
312.           // --------------------------------------  
313.           if (Point.dist(c.center, p) <= c.radius) {  
314.             // 新しい三角形を作り、一時ハッシュに入れる  
315.             addElementToRedundanciesMap(tmpTriangleSet,  
316.               new Triangle(p, t.p1, t.p2));  
317.             addElementToRedundanciesMap(tmpTriangleSet,  
318.               new Triangle(p, t.p2, t.p3));  
319.             addElementToRedundanciesMap(tmpTriangleSet,  
320.               new Triangle(p, t.p3, t.p1));  
321.               
322.             // 旧い三角形をリストから削除  
323.             tIter.remove();              
324.           }  
325.         }  
326.           
327.         // --------------------------------------  
328.         // 一時ハッシュのうち、重複のないものを三角形リストに追加   
329.         // --------------------------------------  
330.         for(Iterator tmpIter = tmpTriangleSet.entrySet().iterator();  
331.             tmpIter.hasNext();) {  
332.   
333.           Map.Entry entry = (Map.Entry)tmpIter.next();  
334.           Triangle t = (Triangle)entry.getKey();  
335.             
336.           boolean isUnique =   
337.               ((Boolean)entry.getValue()).booleanValue();  
338.   
339.           if(isUnique) {  
340.             triangleSet.add(t);  
341.           }  
342.         }  
343.       }  
344.         
345.       // 最後に、外部三角形の頂点を削除  
346.       for(Iterator tIter = triangleSet.iterator(); tIter.hasNext();){  
347.         // 三角形リストから三角形を取り出して  
348.         Triangle t = (Triangle)tIter.next();  
349.         // もし外部三角形の頂点を含む三角形があったら、それを削除  
350.         if(hugeTriangle.hasCommonPoints(t)) {  
351.           tIter.remove();  
352.         }  
353.       }  
354.         
355.       return triangleSet;  
356.     } catch (Exception ex) {  
357.       return null;  
358.     }  
359.   }  
360.   
361.   // ======================================  
362.   // 一時ハッシュを使って重複判定  
363.   // hashMap  
364.   //  - Key   : 三角形  
365.   //  - Value : 重複していないかどうか  
366.   //            - 重複していない : true  
367.   //            - 重複している   : false  
368.   // ======================================  
369.   private void addElementToRedundanciesMap  
370.       (HashMap<Triangle, Boolean> hashMap, Triangle t) {  
371.     if (hashMap.containsKey(t)) {  
372.       // 重複あり : Keyに対応する値にFalseをセット  
373.       hashMap.put(t, new Boolean(false));  
374.     } else {  
375.       // 重複なし : 新規追加し、  
376.       hashMap.put(t, new Boolean(true));  
377.     }  
378.   }  
379.     
380.   // ======================================  
381.   // 最初に必要な巨大三角形を求める  
382.   // ======================================  
383.   // 画面全体を包含する正三角形を求める  
384.   private Triangle getHugeTriangle() {  
385.     return getHugeTriangle(new PVector(0, 0),   
386.                            new PVector(width, height));      
387.   }  
388.   // 任意の矩形を包含する正三角形を求める  
389.   // 引数には矩形の左上座標および右下座標を与える  
390.   private Triangle getHugeTriangle(PVector start, PVector end) {  
391.     // start: 矩形の左上座標、  
392.     // end  : 矩形の右下座標…になるように  
393.     if(end.x < start.x) {  
394.       float tmp = start.x;  
395.       start.x = end.x;  
396.       end.x = tmp;  
397.     }  
398.     if(end.y < start.y) {  
399.       float tmp = start.y;  
400.       start.y = end.y;  
401.       end.y = tmp;  
402.     }  
403.       
404.     // 1) 与えられた矩形を包含する円を求める  
405.     //      円の中心 c = 矩形の中心  
406.     //      円の半径 r = |p - c| + ρ  
407.     //    ただし、pは与えられた矩形の任意の頂点  
408.     //    ρは任意の正数  
409.     Point center = new Point( (end.x - start.x) / 2.0,  
410.                               (end.y - start.y) / 2.0 );  
411.     float radius = Point.dist(center, start) + 1.0;  
412.       
413.     // 2) その円に外接する正三角形を求める  
414.     //    重心は、円の中心に等しい  
415.     //    一辺の長さは 2√3･r  
416.     float x1 = center.x - sqrt(3) * radius;  
417.     float y1 = center.y - radius;  
418.     Point p1 = new Point(x1, y1);  
419.       
420.     float x2 = center.x + sqrt(3) * radius;  
421.     float y2 = center.y - radius;  
422.     Point p2 = new Point(x2, y2);  
423.       
424.     float x3 = center.x;  
425.     float y3 = center.y + 2 * radius;  
426.     Point p3 = new Point(x3, y3);  
427.   
428.     return new Triangle(p1, p2, p3);      
429.   }  
430.     
431.   // ======================================  
432.   // 三角形を与えてその外接円を求める  
433.   // ======================================  
434.   private Circle getCircumscribedCirclesOfTriangle(Triangle t) {  
435.     // 三角形の各頂点座標を (x1, y1), (x2, y2), (x3, y3) とし、  
436.     // その外接円の中心座標を (x, y) とすると、  
437.     //     (x - x1) * (x - x1) + (y - y1) * (y - y1)  
438.     //   = (x - x2) * (x - x2) + (y - y2) * (y - y2)  
439.     //   = (x - x3) * (x - x3) + (y - y3) * (y - y3)  
440.     // より、以下の式が成り立つ  
441.     //  
442.     // x = { (y3 - y1) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)  
443.     //     + (y1 - y2) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1)} / c  
444.     //  
445.     // y = { (x1 - x3) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)  
446.     //     + (x2 - x1) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1)} / c  
447.     //  
448.     // ただし、  
449.     //   c = 2 * {(x2 - x1) * (y3 - y1) - (y2 - y1) * (x3 - x1)}  
450.       
451.     float x1 = t.p1.x;  
452.     float y1 = t.p1.y;  
453.     float x2 = t.p2.x;  
454.     float y2 = t.p2.y;  
455.     float x3 = t.p3.x;  
456.     float y3 = t.p3.y;  
457.       
458.     float c = 2.0 * ((x2 - x1) * (y3 - y1) - (y2 - y1) * (x3 - x1));  
459.     float x = ((y3 - y1) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)  
460.              + (y1 - y2) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1))/c;  
461.     float y = ((x1 - x3) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)  
462.              + (x2 - x1) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1))/c;  
463.     Point center = new Point(x, y);  
464.       
465.     // 外接円の半径 r は、半径から三角形の任意の頂点までの距離に等しい  
466.     float r = Point.dist(center, t.p1);  
467.       
468.     return new Circle(center, r);  
469.   }  
470. }  
471.   
472. // **************************************  
473. //  
474. // 三角形クラス  
475. //  
476. // **************************************  
477.   
478. class Triangle{  
479.   public Point p1, p2, p3;  // 頂点  
480.     
481.   // ======================================  
482.   // コンストラクタ  
483.   // 3頂点を与えて三角形をつくるよ  
484.   // 頂点はPointで与えてもOK  
485.   // ======================================  
486.   public Triangle(PVector p1, PVector p2, PVector p3){  
487.     this.p1 = p1 instanceof Point ? (Point)p1 : new Point(p1);  
488.     this.p2 = p2 instanceof Point ? (Point)p2 : new Point(p2);  
489.     this.p3 = p3 instanceof Point ? (Point)p3 : new Point(p3);  
490.   }  
491.     
492.   // ======================================  
493.   // 同値判定  
494.   // ======================================  
495.   public boolean equals(Object obj) {  
496.     try {  
497.       Triangle t = (Triangle)obj;  
498.       // ※ 同値判定に頂点を用いると、  
499.       // 三角形の頂点の順番を網羅的に考慮する分条件判定が多くなる。  
500.       return(p1.equals(t.p1) && p2.equals(t.p2) && p3.equals(t.p3) ||  
501.              p1.equals(t.p2) && p2.equals(t.p3) && p3.equals(t.p1) ||  
502.              p1.equals(t.p3) && p2.equals(t.p1) && p3.equals(t.p2) ||  
503.                 
504.              p1.equals(t.p3) && p2.equals(t.p2) && p3.equals(t.p1) ||  
505.              p1.equals(t.p2) && p2.equals(t.p1) && p3.equals(t.p3) ||  
506.              p1.equals(t.p1) && p2.equals(t.p3) && p3.equals(t.p2) );  
507.     } catch (Exception ex) {  
508.       return false;  
509.     }  
510.   }  
511.       
512.   // ======================================  
513.   // ハッシュ表で管理できるよう、hashCodeをオーバーライド  
514.   // ======================================  
515.   public int hashCode() {  
516.     return 0;  
517.   }  
518.     
519.   // ======================================  
520.   // 他の三角形と共有点を持つか  
521.   // ======================================    
522.   public boolean hasCommonPoints(Triangle t) {  
523.     return (p1.equals(t.p1) || p1.equals(t.p2) || p1.equals(t.p3) ||  
524.             p2.equals(t.p1) || p2.equals(t.p2) || p2.equals(t.p3) ||  
525.             p3.equals(t.p1) || p3.equals(t.p2) || p3.equals(t.p3) );  
526.   }  
527. }  
528.   
529. // **************************************  
530. //  
531. // 円クラス  
532. //  
533. // **************************************  
534.   
535. class Circle {  
536.   // 中心座標と半径  
537.   Point center;  
538.   float radius;  
539.     
540.   // ======================================  
541.   // コンストラクタ  
542.   // 中心座標と半径を与えて円をつくるよ  
543.   // ======================================  
544.   public Circle(PVector c, float r){  
545.     this.center = c instanceof Point ? (Point) c : new Point(c);  
546.     this.radius = r;  
547.   }  
548. }  
549.   
550. // **************************************  
551. //  
552. // 点クラス  
553. //  
554. // **************************************  
555.   
556. class Point extends PVector {  
557.   // ======================================  
558.   // コンストラクタ  
559.   // ======================================  
560.   public Point() {  
561.     super();  
562.   }  
563.   public Point(float x, float y) {  
564.     super(x, y);  
565.   }  
566.   public Point(float x, float y, float z) {  
567.     super(x, y, z);  
568.   }  
569.   public Point(PVector v) {  
570.     this.x = v.x;  
571.     this.y = v.y;  
572.     this.z = v.z;  
573.   }  
574.     
575.   // ======================================  
576.   // 同値判定  
577.   // ======================================  
578.   public boolean equals(Object o) {  
579.     boolean retVal;  
580.     try {  
581.       PVector p = (PVector)o;  
582.       return (x == p.x && y == p.y && z == p.z);  
583.     } catch (Exception ex) {  
584.       return false;  
585.     }  
586.   }  
587. }  

// ∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴
// 
// 状態遷移に関するクラス群
//
// ∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵


// **************************************
//
// 画面遷移用クラス
//
// **************************************
class StateTransitionEffect implements Scene {

  // ======================================
  // 遷移にかかる時間と、
  // フェード効果発現までの時間（変更可能）
  // ======================================
  private final int MAX_TIME   = 90;
  private final int FADE_DELAY = 80;

  private PImage nextSceneImage;
  private Fragments fragments;
  private int time;
  private Scene cur, next;
  
  // ======================================
  // コンストラクタ
  // 
  // Scene
  //  - cur  : 前状態
  //  - next : 次状態
  // ======================================
  StateTransitionEffect(Scene cur, Scene next) {
    this.cur = cur;
    this.next = next;
    
    nextSceneImage = createImage(width, height, RGB);

    cur.setEnable(false);
    next.setEnable(false);
    
    fragments = new Fragments(50);
    time = 0;
  }
  
  Scene update(){
    camera();
    noStroke();
    next.update();
    
    int a;  // アルファ値（フェード効果で使用）
    
    loadPixels();
    for(int i = 0; i < pixels.length; i++)
      nextSceneImage.pixels[i] = pixels[i];
    background(nextSceneImage);
    
    // 次状態のフェードイン効果
    /* --------------------------------------------------
    a = (int)(255 * (float)(MAX_TIME - time) / MAX_TIME);
    fill(0, a);    noSmooth();
    rect(0, 0, width, height);
    -------------------------------------------------- */
    
    // 破片の描画
    fragments.update();
    
    // 破片のフェードアウト効果
    if (FADE_DELAY <= time) {
      a = (int)(255*(float)(time-FADE_DELAY)/(MAX_TIME-FADE_DELAY));

      loadPixels();
      // アルファ合成
      for(int i = 0; i < pixels.length; i++) {
        int fg = nextSceneImage.pixels[i];
        int bg = pixels[i];
        
        int fR = (0x00FF0000 & fg) >>> 16;
        int fG = (0x0000FF00 & fg) >>> 8;
        int fB =  0x000000FF & fg;
      
        int bR = (0x00FF0000 & bg) >>> 16;
        int bG = (0x0000FF00 & bg) >>> 8;
        int bB =  0x000000FF & bg;
      
        int rR = (((fR - bR) * a) >>> 8 ) + bR;
        int rG = (((fG - bG) * a) >>> 8 ) + bG;
        int rB = (((fB - bB) * a) >>> 8 ) + bB;
        
        pixels[i] = 0xFF000000 | (rR << 16) | (rG << 8) | rB;
      }
      updatePixels();
    }
    
    if(time++ < MAX_TIME) return this;
    
    next.setEnable(true);
    return next;
  }
  
  void setEnable(boolean isEnable) { 
    /* なにもしない */
  }
}

// **************************************
//
// 破片の集合クラス
//
// **************************************
class Fragments {
  PImage tex;
  List<Fragment> f;
  
  Fragments(int nPoints) {
    tex = createImage(width, height, RGB);
    loadPixels();
    for(int i = 0; i < pixels.length; i++) {
      tex.pixels[i] = pixels[i];
    }
    
    // 破片セット
    f = new ArrayList<Fragment>();
    
    // Delaunay分割
    List<PVector> pList = new ArrayList<PVector>();
    pList.add(new Point(0, 0));
    pList.add(new Point(width, 0));
    pList.add(new Point(width, height));
    pList.add(new Point(0, height));
    for(int i = 0; i < nPoints; i++) {
      pList.add(new Point(random(width), random(height)));
    }
    DelaunayTriangles delaunay = new DelaunayTriangles(pList);
    
    // Delaunay三角集合をリスト化
    HashSet tSet = delaunay.getDelaunayTriangulationSet();
    for(Iterator it = tSet.iterator(); it.hasNext();) {
      f.add(new Fragment((Triangle)it.next(), tex));
    }
  }
  
  void update() {
    for(Iterator it = f.iterator(); it.hasNext();) {
      Fragment fragment = (Fragment)it.next();
      fragment.update();
    }
  }
}

// **************************************
//
// 破片クラス
//
// **************************************
class Fragment {
  // PVector[] texCoords;
  PVector[] vertices;
  PImage tex;  // テクスチャ
  
  // 並進成分・回転角
  private float x, y, z, rx, ry, rz;
  private float dx, dy, dz, drx, dry, drz;
  private float ddx, ddy, ddz;
  
  // 与えられた三角形の重心
  private float cx, cy, cz;
  
  Fragment(Triangle t, PImage tex) {
    this.tex = tex;
    
    // 頂点座標をセット
    vertices = new PVector[3];
    vertices[0] = t.p1;
    vertices[1] = t.p2;
    vertices[2] = t.p3;
    
    // 重心を計算
    cx = (t.p1.x + t.p2.x + t.p3.x)/3.0;
    cy = (t.p1.y + t.p2.y + t.p3.y)/3.0;
    cz = (t.p1.z + t.p2.z + t.p3.z)/3.0;
    
    // 並進・回転の初期値を設定
    x = y = z = 0;
    rx = ry = rz = 0;
    
    // ======================================
    // 速度・加速度を設定（変更可能）
    // ======================================
    dx =  random(-0.5, 0.5);
    dy = -random( 1  , 6  );
    dz =  random(-0.5, 0.5);
    
    ddx = 0;
    ddy = random(0.2, 0.5);
    ddz = 0;

    drx = radians(random(-2, 2));
    dry = radians(random(-2, 2));
    drz = radians(random(-2, 2));    
  }
  
  void update() {
    noStroke();
    fill(255);
    lights();

    pushMatrix();
    // 並進
    translate(cx + x, cy + y, cz + z);
    
    // 回転  
    rotateX(rx); rotateZ(rz); rotateY(ry);
    
    // 並進
    translate(-cx, -cy, -cz);

    textureMode(IMAGE);
    beginShape(TRIANGLES);
    texture(tex);
    for(int i = 0; i < vertices.length; i++) {
      vertex(vertices[i].x, vertices[i].y,
             vertices[i].x, vertices[i].y);
    }
    endShape();
    popMatrix();
    noLights();
    
    x  += dx;  y  += dy;  z  += dz;
    rx += drx; ry += dry; rz += drz;
    dx += ddx; dy += ddy; dz += ddz;
  }
}


// ∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴
// 
// Delaunay分割に関するクラス群
//
// ∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵∴∵

// **************************************
//
// Delaunay分割用クラス
//
// **************************************

class DelaunayTriangles {
  private List<PVector> pointList;
  // ======================================
  // コンストラクタ
  // 与えられた点のリストを基にDelaunay分割を行う
  // ======================================
  public DelaunayTriangles(List<PVector> pointList) {
    this.pointList = pointList;
  }
  
  
  // ======================================
  // Delaunay三角分割を行う
  // ======================================
  public HashSet<Triangle>
      getDelaunayTriangulationSet() {
    
    // 三角形リストを初期化
    HashSet<Triangle> triangleSet = new HashSet<Triangle>();
    
    // 巨大な外部三角形をリストに追加
    Triangle hugeTriangle = getHugeTriangle();
    triangleSet.add(hugeTriangle);

    try {
      // --------------------------------------
      // 点を逐次添加し、反復的に三角分割を行う
      // --------------------------------------
      for(Iterator pIter = pointList.iterator(); pIter.hasNext();) {
        Object element = pIter.next();
        Point p = element instanceof Point ? 
            (Point)element : new Point((PVector)element);
        
        // --------------------------------------
        // 追加候補の三角形を保持する一時ハッシュ
        // --------------------------------------
        // 追加候補の三角形のうち、「重複のないものだけ」を
        // 三角形リストに新規追加する
        //          → 重複管理のためのデータ構造
        // tmpTriangleSet
        //  - Key   : 三角形
        //  - Value : 重複していないかどうか
        //            - 重複していない : true
        //            - 重複している   : false
        // --------------------------------------
        HashMap<Triangle, Boolean> tmpTriangleSet 
          = new HashMap<Triangle, Boolean>();

        // --------------------------------------
        // 現在の三角形リストから要素を一つずつ取り出して、
        // 与えられた点が各々の三角形の外接円の中に含まれるかどうか判定
        // --------------------------------------
        for(Iterator tIter=triangleSet.iterator(); tIter.hasNext();){
          // 三角形リストから三角形を取り出して…
          Triangle t = (Triangle)tIter.next();
              
          // その外接円を求める。
          Circle c = getCircumscribedCirclesOfTriangle(t);
              
          // --------------------------------------
          // 追加された点が外接円内部に存在する場合、
          // その外接円を持つ三角形をリストから除外し、
          // 新たに分割し直す
          // --------------------------------------
          if (Point.dist(c.center, p) <= c.radius) {
            // 新しい三角形を作り、一時ハッシュに入れる
            addElementToRedundanciesMap(tmpTriangleSet,
              new Triangle(p, t.p1, t.p2));
            addElementToRedundanciesMap(tmpTriangleSet,
              new Triangle(p, t.p2, t.p3));
            addElementToRedundanciesMap(tmpTriangleSet,
              new Triangle(p, t.p3, t.p1));
            
            // 旧い三角形をリストから削除
            tIter.remove();            
          }
        }
        
        // --------------------------------------
        // 一時ハッシュのうち、重複のないものを三角形リストに追加 
        // --------------------------------------
        for(Iterator tmpIter = tmpTriangleSet.entrySet().iterator();
            tmpIter.hasNext();) {

          Map.Entry entry = (Map.Entry)tmpIter.next();
          Triangle t = (Triangle)entry.getKey();
          
          boolean isUnique = 
              ((Boolean)entry.getValue()).booleanValue();

          if(isUnique) {
            triangleSet.add(t);
          }
        }
      }
      
      // 最後に、外部三角形の頂点を削除
      for(Iterator tIter = triangleSet.iterator(); tIter.hasNext();){
        // 三角形リストから三角形を取り出して
        Triangle t = (Triangle)tIter.next();
        // もし外部三角形の頂点を含む三角形があったら、それを削除
        if(hugeTriangle.hasCommonPoints(t)) {
          tIter.remove();
        }
      }
      
      return triangleSet;
    } catch (Exception ex) {
      return null;
    }
  }

  // ======================================
  // 一時ハッシュを使って重複判定
  // hashMap
  //  - Key   : 三角形
  //  - Value : 重複していないかどうか
  //            - 重複していない : true
  //            - 重複している   : false
  // ======================================
  private void addElementToRedundanciesMap
      (HashMap<Triangle, Boolean> hashMap, Triangle t) {
    if (hashMap.containsKey(t)) {
      // 重複あり : Keyに対応する値にFalseをセット
      hashMap.put(t, new Boolean(false));
    } else {
      // 重複なし : 新規追加し、
      hashMap.put(t, new Boolean(true));
    }
  }
  
  // ======================================
  // 最初に必要な巨大三角形を求める
  // ======================================
  // 画面全体を包含する正三角形を求める
  private Triangle getHugeTriangle() {
    return getHugeTriangle(new PVector(0, 0), 
                           new PVector(width, height));    
  }
  // 任意の矩形を包含する正三角形を求める
  // 引数には矩形の左上座標および右下座標を与える
  private Triangle getHugeTriangle(PVector start, PVector end) {
    // start: 矩形の左上座標、
    // end  : 矩形の右下座標…になるように
    if(end.x < start.x) {
      float tmp = start.x;
      start.x = end.x;
      end.x = tmp;
    }
    if(end.y < start.y) {
      float tmp = start.y;
      start.y = end.y;
      end.y = tmp;
    }
    
    // 1) 与えられた矩形を包含する円を求める
    //      円の中心 c = 矩形の中心
    //      円の半径 r = |p - c| + ρ
    //    ただし、pは与えられた矩形の任意の頂点
    //    ρは任意の正数
    Point center = new Point( (end.x - start.x) / 2.0,
                              (end.y - start.y) / 2.0 );
    float radius = Point.dist(center, start) + 1.0;
    
    // 2) その円に外接する正三角形を求める
    //    重心は、円の中心に等しい
    //    一辺の長さは 2√3･r
    float x1 = center.x - sqrt(3) * radius;
    float y1 = center.y - radius;
    Point p1 = new Point(x1, y1);
    
    float x2 = center.x + sqrt(3) * radius;
    float y2 = center.y - radius;
    Point p2 = new Point(x2, y2);
    
    float x3 = center.x;
    float y3 = center.y + 2 * radius;
    Point p3 = new Point(x3, y3);

    return new Triangle(p1, p2, p3);    
  }
  
  // ======================================
  // 三角形を与えてその外接円を求める
  // ======================================
  private Circle getCircumscribedCirclesOfTriangle(Triangle t) {
    // 三角形の各頂点座標を (x1, y1), (x2, y2), (x3, y3) とし、
    // その外接円の中心座標を (x, y) とすると、
    //     (x - x1) * (x - x1) + (y - y1) * (y - y1)
    //   = (x - x2) * (x - x2) + (y - y2) * (y - y2)
    //   = (x - x3) * (x - x3) + (y - y3) * (y - y3)
    // より、以下の式が成り立つ
    //
    // x = { (y3 - y1) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)
    //     + (y1 - y2) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1)} / c
    //
    // y = { (x1 - x3) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)
    //     + (x2 - x1) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1)} / c
    //
    // ただし、
    //   c = 2 * {(x2 - x1) * (y3 - y1) - (y2 - y1) * (x3 - x1)}
    
    float x1 = t.p1.x;
    float y1 = t.p1.y;
    float x2 = t.p2.x;
    float y2 = t.p2.y;
    float x3 = t.p3.x;
    float y3 = t.p3.y;
    
    float c = 2.0 * ((x2 - x1) * (y3 - y1) - (y2 - y1) * (x3 - x1));
    float x = ((y3 - y1) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)
             + (y1 - y2) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1))/c;
    float y = ((x1 - x3) * (x2 * x2 - x1 * x1 + y2 * y2 - y1 * y1)
             + (x2 - x1) * (x3 * x3 - x1 * x1 + y3 * y3 - y1 * y1))/c;
    Point center = new Point(x, y);
    
    // 外接円の半径 r は、半径から三角形の任意の頂点までの距離に等しい
    float r = Point.dist(center, t.p1);
    
    return new Circle(center, r);
  }
}

// **************************************
//
// 三角形クラス
//
// **************************************

class Triangle{
  public Point p1, p2, p3;  // 頂点
  
  // ======================================
  // コンストラクタ
  // 3頂点を与えて三角形をつくるよ
  // 頂点はPointで与えてもOK
  // ======================================
  public Triangle(PVector p1, PVector p2, PVector p3){
    this.p1 = p1 instanceof Point ? (Point)p1 : new Point(p1);
    this.p2 = p2 instanceof Point ? (Point)p2 : new Point(p2);
    this.p3 = p3 instanceof Point ? (Point)p3 : new Point(p3);
  }
  
  // ======================================
  // 同値判定
  // ======================================
  public boolean equals(Object obj) {
    try {
      Triangle t = (Triangle)obj;
      // ※ 同値判定に頂点を用いると、
      // 三角形の頂点の順番を網羅的に考慮する分条件判定が多くなる。
      return(p1.equals(t.p1) && p2.equals(t.p2) && p3.equals(t.p3) ||
             p1.equals(t.p2) && p2.equals(t.p3) && p3.equals(t.p1) ||
             p1.equals(t.p3) && p2.equals(t.p1) && p3.equals(t.p2) ||
              
             p1.equals(t.p3) && p2.equals(t.p2) && p3.equals(t.p1) ||
             p1.equals(t.p2) && p2.equals(t.p1) && p3.equals(t.p3) ||
             p1.equals(t.p1) && p2.equals(t.p3) && p3.equals(t.p2) );
    } catch (Exception ex) {
      return false;
    }
  }
    
  // ======================================
  // ハッシュ表で管理できるよう、hashCodeをオーバーライド
  // ======================================
  public int hashCode() {
    return 0;
  }
  
  // ======================================
  // 他の三角形と共有点を持つか
  // ======================================  
  public boolean hasCommonPoints(Triangle t) {
    return (p1.equals(t.p1) || p1.equals(t.p2) || p1.equals(t.p3) ||
            p2.equals(t.p1) || p2.equals(t.p2) || p2.equals(t.p3) ||
            p3.equals(t.p1) || p3.equals(t.p2) || p3.equals(t.p3) );
  }
}

// **************************************
//
// 円クラス
//
// **************************************

class Circle {
  // 中心座標と半径
  Point center;
  float radius;
  
  // ======================================
  // コンストラクタ
  // 中心座標と半径を与えて円をつくるよ
  // ======================================
  public Circle(PVector c, float r){
    this.center = c instanceof Point ? (Point) c : new Point(c);
    this.radius = r;
  }
}

// **************************************
//
// 点クラス
//
// **************************************

class Point extends PVector {
  // ======================================
  // コンストラクタ
  // ======================================
  public Point() {
    super();
  }
  public Point(float x, float y) {
    super(x, y);
  }
  public Point(float x, float y, float z) {
    super(x, y, z);
  }
  public Point(PVector v) {
    this.x = v.x;
    this.y = v.y;
    this.z = v.z;
  }
  
  // ======================================
  // 同値判定
  // ======================================
  public boolean equals(Object o) {
    boolean retVal;
    try {
      PVector p = (PVector)o;
      return (x == p.x && y == p.y && z == p.z);
    } catch (Exception ex) {
      return false;
    }
  }
}

サンプルでは、デモ用の状態クラスをひとつ作り、Scene1 と名付けている。

テスト用のコードは以下の通り。

+ expand sourceview plainprint?

1. Scene scene;  
2.   
3. void setup() {  
4.   size(400, 300, P3D);  
5.   scene = new Scene1();  
6. }  
7. void draw() {  
8.   scene = scene.update();  
9. }  
10.   
11. // =======================================================  
12. // デモ用の状態クラス  
13. // =======================================================  
14. class Scene1 implements Scene {  
15.   float h, p, b;     // ヘディング・ピッチ・バンク回転量  
16.   float dh, dp, db;  // 角速度  
17.   int objColor, bgColor;  
18.   boolean isEnable;  
19.     
20.   
21.   Scene1() {  
22.     // 色の付け方はてきとうです。  
23.     objColor = color(random(100, 200),   
24.       random(100, 200),   
25.       random(100, 200));  
26.     bgColor = color( red(objColor) + 55, green(objColor) + 55, blue(objColor) + 55);  
27.       
28.     // 回転量・並進量を設定  
29.     h = random(0, 360);  
30.     p = random(-90, 90);  
31.     b = random(0, 360);  
32.     dh = random(-1, 1);  
33.     db = random(-1, 1);  
34.     dp = random(-1, 1);  
35.       
36.     isEnable = true;  
37.   }  
38.     
39.   Scene update() {  
40.     camera();  
41.     lights();  
42.       
43.     background(bgColor);  
44.       
45.     noStroke();  
46.     fill(objColor);  
47.       
48.     pushMatrix();  
49.     translate(width/2, height/2, -width/2);  
50.     rotateY(radians(h));  
51.     rotateX(radians(p));  
52.     rotateZ(radians(b));  
53.     box(250);  
54.     popMatrix();  
55.       
56.     h += dh;  
57.     p += dp;  
58.     b += db;  
59.       
60.     noLights();  
61.           
62.     if (mousePressed && isEnable) {  
63.       return new StateTransitionEffect(this, new Scene1());  
64.     } else {  
65.       return this;  
66.     }  
67.   }  
68.     
69.   void setEnable(boolean isEnable) {  
70.     this.isEnable = isEnable;  
71.   }  
72. }  

Scene scene;

void setup() {
  size(400, 300, P3D);
  scene = new Scene1();
}
void draw() {
  scene = scene.update();
}

// =======================================================
// デモ用の状態クラス
// =======================================================
class Scene1 implements Scene {
  float h, p, b;     // ヘディング・ピッチ・バンク回転量
  float dh, dp, db;  // 角速度
  int objColor, bgColor;
  boolean isEnable;
  

  Scene1() {
    // 色の付け方はてきとうです。
    objColor = color(random(100, 200), 
      random(100, 200), 
      random(100, 200));
    bgColor = color( red(objColor) + 55, green(objColor) + 55, blue(objColor) + 55);
    
    // 回転量・並進量を設定
    h = random(0, 360);
    p = random(-90, 90);
    b = random(0, 360);
    dh = random(-1, 1);
    db = random(-1, 1);
    dp = random(-1, 1);
    
    isEnable = true;
  }
  
  Scene update() {
    camera();
    lights();
    
    background(bgColor);
    
    noStroke();
    fill(objColor);
    
    pushMatrix();
    translate(width/2, height/2, -width/2);
    rotateY(radians(h));
    rotateX(radians(p));
    rotateZ(radians(b));
    box(250);
    popMatrix();
    
    h += dh;
    p += dp;
    b += db;
    
    noLights();
        
    if (mousePressed && isEnable) {
      return new StateTransitionEffect(this, new Scene1());
    } else {
      return this;
    }
  }
  
  void setEnable(boolean isEnable) {
    this.isEnable = isEnable;
  }
}